论坛 › ERM公会 | ERM Guild › 这个erm哪里有问题？

十三木人 发表于 2012-5-4 11:37:43

这个erm哪里有问题？

erm来自英雄套装1.0中鬼王斗篷强化，我把67改为196使其能召唤龙巫妖。
但是只要一个英雄装备鬼王斗篷，我方任何英雄打怪后鬼王都会出现在那个英雄身上。
ZVSE
!#VRz932:S^{鬼王斗篷} 强化

招魂术增强30%。此外招魂术等级越高，如出的亡灵等级也越
高。初级：僵尸。中级：幽灵。高级：{龙巫妖}。 ^;
!#UN:A130/10/932;

!?BA0&1000;
!!VRv9631:S0;
!!HEv9555&v9555>-1:A2/130/0/?y1;
!!HEv9555&v9555>-1:S12/?y3;
!!HEv9560&v9560>-1:A2/130/0/?y2;
!!HEv9560&v9560>-1:S12/?y4;
!!VRv9631&y1>0/y3=3:S1;
!!VRv9631&y2>0/y4=3:S2;
!!HEv9555&y1>0/y3=3:A3/130/1/1;
!!HEv9555&y1>0/y3=3:S12/0;
!!HEv9560&y2>0/y4=3:A3/130/1/1;
!!HEv9560&y2>0/y4=3:S12/0;

!?BF&v9631=1;
!!BA:M1/0/?y1/?y8 M1/1/?y2/?y9 M1/2/?y3/?y10 M1/3/?y4/?y11 M1/4/?y5/?y12 M1/5/?y6/?y13 M1/6/?y7/?y14;
!!MA&y1<>-1:Py1/?y15;
!!MA&y2<>-1:Py2/?y16;
!!MA&y3<>-1:Py3/?y17;
!!MA&y4<>-1:Py4/?y18;
!!MA&y5<>-1:Py5/?y19;
!!MA&y6<>-1:Py6/?y20;
!!MA&y7<>-1:Py7/?y21;
!!VRy22:Sy8*y15;
!!VRy23:Sy9*y16;
!!VRy24:Sy10*y17;
!!VRy25:Sy11*y18;
!!VRy26:Sy12*y19;
!!VRy27:Sy13*y20;
!!VRy28:Sy14*y21;
!!VRy29:Sy22+y23+y24+y25+y26+y27+y28;
!!VRv9632:Sy29:300; ~下调召魂数量
!!VRv9632&v9632<1:S1;

!?BF&v9631=2;
!!BA:M1/0/?y1/?y8 M1/1/?y2/?y9 M1/2/?y3/?y10 M1/3/?y4/?y11 M1/4/?y5/?y12 M1/5/?y6/?y13 M1/6/?y7/?y14;
!!MA&y1<>-1:Py1/?y15;
!!MA&y2<>-1:Py2/?y16;
!!MA&y3<>-1:Py3/?y17;
!!MA&y4<>-1:Py4/?y18;
!!MA&y5<>-1:Py5/?y19;
!!MA&y6<>-1:Py6/?y20;
!!MA&y7<>-1:Py7/?y21;
!!VRy22:Sy8*y15;
!!VRy23:Sy9*y16;
!!VRy24:Sy10*y17;
!!VRy25:Sy11*y18;
!!VRy26:Sy12*y19;
!!VRy27:Sy13*y20;
!!VRy28:Sy14*y21;
!!VRy29:Sy22+y23+y24+y25+y26+y27+y28;
!!VRv9633:Sy29:300; ~下调召魂数量
!!VRv9633&v9633<1:S1;

!?BA1&v9631=1;
!!HEv9555:A1/130/1;
!!HEv9555:S12/3;
!!VRv9631:S0;
!!HEv9555:O?y1;
!!FU&y1<0:E;
!!IF:Q446/21/196/1^通过召魂术，你的英雄能把%V9632个敌军阵亡者变成龙巫妖。^;
!!HEv9555:C2/196/v9632/1;
!!UN:R1;
!!VRv9632:S0;

!?BA1&v9631=2;
!!HEv9560:A1/130/1;
!!HEv9560:S12/3;
!!VRv9631:S0;
!!HEv9560:O?y1;
!!FU&y1<0:E;
!!IF:Q446/21/196/1^通过召魂术，你的英雄能把%V9633个敌军阵亡者变成龙巫妖。^;
!!HEv9560:C2/196/v9633/1;
!!UN:R1;
!!VRv9633:S0;

寻梦人 发表于 2012-5-4 11:45:29

问题：
1、没有读取v9555、v9560的值；
2、防守方的招魂计算错误；应该是M0！

兽哥哥 发表于 2012-5-4 11:49:53

寻梦V5，虽然说我没看懂，不知LZ又是否谁的马甲？

十三木人 发表于 2012-5-4 12:42:01

回2楼，感谢帮助，现在没有鬼王斗篷乱飞的问题了。
回3楼，我是新人。

沧海一粟 发表于 2012-5-4 12:44:05

原帖由 寻梦人 于 2012-5-4 11:45 发表 http://www.h3wog.com/images/common/back.gif
问题：
1、没有读取v9555、v9560的值；
2、防守方的招魂计算错误；应该是M0！

LZ如果是这样只简单地截取其中一部分代码很可能会引起错误的哦。

另外，好像当初写时确实把防守方计算给疏忽了，唉，人老了头容易犯晕。;ekow;

[ 本帖最后由 沧海一粟 于 2012-5-4 12:53 编辑 ]

十三木人 发表于 2012-5-4 12:53:21

回复 5# 的帖子

明白自己错在哪了，确实忘记复制读取英雄的代码了。
不过这个强化的有点夸张，招出来的比打死的敌人还要多，想要减少数目只要把300改大就可以了吧？

沧海一粟 发表于 2012-5-4 12:56:22

回复 6# 的帖子

嗯，我当初写它是主要以诸神地图为基石设计的，换成恐怖骑士还马马虎虎，召龙巫妖肯定太强了。
300的设定也是主要基于恐怖骑士（生命值150的2倍左右）来订的，龙巫妖我觉得改成2000差不多。

关于那两套装备还是有点太强了，有空还是会更新下，平衡点，诸神套准备搞成组合宝物得了。

[ 本帖最后由 沧海一粟 于 2012-5-4 12:59 编辑 ]

十三木人 发表于 2012-5-4 15:32:51

在使用时，又发现几个问题
1.当击败敌方英雄后，如果敌方英雄装备斗篷类宝物，会取代鬼王斗篷
2.升级后会出现新技能把招魂术挤出去，这个到是影响不大，只是相当于给了英雄一个新技能，招魂术依然起作用
对照帮助文件后感觉是这几个代码的关系
!!HEv9555&y1>0/y3=3:A3/130/1/1;移去进攻方英雄的鬼王斗篷
!!HEv9555&y1>0/y3=3:S12/0;移去进攻方英雄的招魂术
!!HEv9560&y2>0/y4=3:A3/130/1/1;移去防守方英雄的鬼王斗篷
!!HEv9560&y2>0/y4=3:S12/0;移去防守方英雄的招魂术
应该要怎么解决？

十三木人 发表于 2012-5-4 17:50:16

第一个问题解决了，把鬼王替换成别的什么就好了，打完在替换回来
第二个没有办法，就算替换也会导致招魂的位置变化，有什么建议吗？

沧海一粟 发表于 2012-5-4 18:05:15

回复 9# 的帖子

用HE:S$1/$2/1 命令去试试，也许能行
你的第一个也不失好办法，譬如说换成大使披风什么的垃圾。记得改好了发上来看看

骷髅召唤师 发表于 2012-5-4 18:37:28

回复 10# 的帖子

招魂的位置变化可以用HE:S$1/$2/1 命令来解决，但是要用到V变量

hellmatrix 发表于 2012-5-4 23:00:03

还没搞定么，我还准备抄下来试试看呢

十三木人 发表于 2012-5-5 08:20:47

这个修正了鬼王斗篷战后会被别的披风代掉的问题。
至于招魂的位置问题，无能为力。招魂必然会在最后一个，要修正招魂位置就要把每个技能都向后移一位。
还有一个bug，由于是通过检测敌人的血量来增加怪物，所以就算敌人逃跑了，一个都没打死，还是会照常招魂。
ZVSE
!#VRz932:S^{鬼王斗篷} 强化

招魂术增强30%。此外招魂术等级越高，如出的亡灵等级也越
高。初级：僵尸。中级：幽灵。高级：{龙巫妖}。 ^;
!#UN:A130/10/932;

!?BA0&1000;
!!VRv9631:S0;

!!BA:H0/?v9555;
!!HEv9555&v9555>-1:A2/130/0/?y1;
!!HEv9555&v9555>-1:S12/?y3;

!!BA:H1/?v9560;
!!HEv9560&v9560>-1:A2/130/0/?y2;
!!HEv9560&v9560>-1:S12/?y4;

!!VRv9631&y1>0/y3=3:S1;
!!VRv9631&y2>0/y4=3:S2;

!!HEv9555&y1>0/y3=3:A3/130/1/1;
!!HEv9555&y1>0/y3=3:A1/109/1;
!!HEv9555&y1>0/y3=3:S12/0;

!!HEv9560&y2>0/y4=3:A3/130/1/1;
!!HEv9560&y2>0/y4=3:A1/109/1;
!!HEv9560&y2>0/y4=3:S12/0;

!?BF&v9631=1;
!!BA:M1/0/?y1/?y8 M1/1/?y2/?y9 M1/2/?y3/?y10 M1/3/?y4/?y11 M1/4/?y5/?y12 M1/5/?y6/?y13 M1/6/?y7/?y14;
!!MA&y1<>-1:Py1/?y15;
!!MA&y2<>-1:Py2/?y16;
!!MA&y3<>-1:Py3/?y17;
!!MA&y4<>-1:Py4/?y18;
!!MA&y5<>-1:Py5/?y19;
!!MA&y6<>-1:Py6/?y20;
!!MA&y7<>-1:Py7/?y21;
!!VRy22:Sy8*y15;
!!VRy23:Sy9*y16;
!!VRy24:Sy10*y17;
!!VRy25:Sy11*y18;
!!VRy26:Sy12*y19;
!!VRy27:Sy13*y20;
!!VRy28:Sy14*y21;
!!VRy29:Sy22+y23+y24+y25+y26+y27+y28;
!!VRv9632:Sy29:1800; ~下调召魂数量
!!VRv9632&v9632<1:S1;

!?BF&v9631=2;
!!BA:M0/0/?y1/?y8 M0/1/?y2/?y9 M0/2/?y3/?y10 M0/3/?y4/?y11 M0/4/?y5/?y12 M0/5/?y6/?y13 M0/6/?y7/?y14;
!!MA&y1<>-1:Py1/?y15;
!!MA&y2<>-1:Py2/?y16;
!!MA&y3<>-1:Py3/?y17;
!!MA&y4<>-1:Py4/?y18;
!!MA&y5<>-1:Py5/?y19;
!!MA&y6<>-1:Py6/?y20;
!!MA&y7<>-1:Py7/?y21;
!!VRy22:Sy8*y15;
!!VRy23:Sy9*y16;
!!VRy24:Sy10*y17;
!!VRy25:Sy11*y18;
!!VRy26:Sy12*y19;
!!VRy27:Sy13*y20;
!!VRy28:Sy14*y21;
!!VRy29:Sy22+y23+y24+y25+y26+y27+y28;
!!VRv9633:Sy29:1800; ~下调召魂数量
!!VRv9633&v9633<1:S1;

!?BA1&v9631=1;
!!HEv9555:A3/109/1/1;
!!HEv9555:A1/130/1;
!!HEv9555:S12/3;
!!VRv9631:S0;
!!HEv9555:O?y1;
!!FU&y1<0:E;
!!IF:Q446/21/196/1^通过召魂术，你的英雄能把%V9632个敌军阵亡者变成龙巫妖。^;
!!HEv9555:C2/196/v9632/1;
!!UN:R1;
!!VRv9632:S0;

!?BA1&v9631=2;
!!HEv9560:A3/109/1/1;
!!HEv9560:A1/130/1;
!!HEv9560:S12/3;
!!VRv9631:S0;
!!HEv9560:O?y1;
!!FU&y1<0:E;
!!IF:Q446/21/196/1^通过召魂术，你的英雄能把%V9633个敌军阵亡者变成龙巫妖。^;
!!HEv9560:C2/196/v9633/1;
!!UN:R1;
!!VRv9633:S0;

查看完整版本: 这个erm哪里有问题？