请教一下!这是防御术加强部分脚本!
ZVSE** function to offset skill levels
** offset skill levels for armorer, resistance, sorcery
!!BA:H0/?v7054;
!!BA:H1/?v7055;
!!FU7026&v7054>-1:Pv7054/0;
!!FU7026&v7055>-1:Pv7055/0;
** reset skill levels for armorer, resistance, sorcery
!!BU:C?y-9;
!!FU7026&v7054>-1/y-9=1:Pv7054/1;
!!FU7026&v7055>-1/y-9=1:Pv7055/1;
!?FU7026;
x1=hero
x2=set/reset
!!HEx1:S23/?y1;
!!HEx1&y1=1/x2=0:S23/22; 这里S23/22是什么意思?10%是怎么得来的?
!!HEx1&y1=2/x2=0:S23/23; 这里S23/23是什么意思?15%是怎么得来的?
!!HEx1&y1=3/x2=0:S23/19; 这里S23/19是什么意思?20%是怎么得来的?
!!HEx1&y1=22/x2=1:S23/1;
!!HEx1&y1=23/x2=1:S23/2;
!!HEx1&y1=19/x2=1:S23/3;
!!HEx1:S25/?y2;
!!HEx1&y2=1/x2=0/x1<>140:S25/-3;
!!HEx1&y2=2/x2=0/x1<>140:S25/-2;
!!HEx1&y2=3/x2=0/x1<>140:S25/-1;
!!HEx1&y2=-3/x2=1/x1<>140:S25/1;
!!HEx1&y2=-2/x2=1/x1<>140:S25/2;
!!HEx1&y2=-1/x2=1/x1<>140:S25/3;
!!HEx1&y2=1/x2=0/x1=140:S25/-15;
20%
!!HEx1&y2=2/x2=0/x1=140:S25/-14;
40%
!!HEx1&y2=3/x2=0/x1=140:S25/-17;
60%
!!HEx1&y2=-15/x2=1/x1=140:S25/1;
!!HEx1&y2=-14/x2=1/x1=140:S25/2;
!!HEx1&y2=-17/x2=1/x1=140:S25/3;
************************
!!HEx1:S22/?y9;
!!HEx1&y9=1/x2=0/x1=149:S22/1;
10%
!!HEx1&y9=2/x2=0/x1=149:S22/17;
30%
!!HEx1&y9=3/x2=0/x1=149:S22/19;
50%
!!HEx1&y9=1/x2=1/x1=149:S22/1;
!!HEx1&y9=17/x2=1/x1=149:S22/2;
!!HEx1&y9=19/x2=1/x1=149:S22/3;
************************
[ 本帖最后由 xxb19780916 于 2010-12-22 18:29 编辑 ] 猛人得问题可不是我等可以回答得，我蹲个点，可否？ 同求…… 同蹲点...;ym; ;ym; 寻求真相的群众围观中 研究了一下，结论纯属猜测。供参考和测试。
我猜这些数字可能跟程序的算法有关。不是单纯的靠ERM命令，假如靠ERM的话，应该有MF触发器。
有可能是这样的：
防御术等级＝1时，减少5%伤害
防御术等级＝2时，减少10%伤害
防御术等级＝3时，减少15%伤害
这是我们已知的。程序正常计算方式。
下面是一些网友实测得出的结论，注意，这里的等级是10进制，如果测试时，用内存工具，需要转换成对应的16进制，用ERM直接写就行了。
防御术等级＝9时，减少40%伤害
防御术等级＝10时，减少50%伤害
防御术等级＝11时，减少60%伤害
防御术等级＝13时，减少20%伤害
防御术等级＝14时，减少40%伤害
防御术等级＝15时，减少60%伤害
防御术等级＝17时，减少5%伤害
防御术等级＝18时，减少10%伤害
防御术等级＝19时，减少20%伤害
防御术等级＝22时，减少????伤害
防御术等级＝23时，减少????伤害
防御术等级＝27时，减少30%伤害
防御术等级＝33时，减少25%伤害
防御术等级＝34时，减少50%伤害
防御术等级＝35时，减少100%伤害
防御术等于22和23时，网友没有给出测试数据，我猜可能应该是10%和15%。那么实际上那段代码或许可以这样写，实际效果是一样的：
!!HEx1&y1=1/x2=0:S23/18;
!!HEx1&y1=2/x2=0:S23/3;
!!HEx1&y1=3/x2=0:S23/13
当然这样写，如果在英雄界面观察辅助技能时，会乱，所以每次回合结束后，再把防御术等级恢复过来：
!!HEx1&y1=22/x2=1:S23/1; 防御术级别=22/x2=1 防御术级别设置为1
!!HEx1&y1=23/x2=1:S23/2; 防御术级别=23/x2=1 防御术级别设置为2
!!HEx1&y1=19/x2=1:S23/3; 防御术级别=19/x2=1 防御术级别设置为3;
我在测试的时候，只查看了内存数据变化，没去看减少的伤害。
战场生成后，内存地址里的数据，在防御术等于1，2，3的时候，确实变成了对应的22，23，19。战后，再恢复成1，2，3。
有兴趣的朋友，可以实际测试下伤害数据，降低的百分比。
进一步猜测，如果这样写：
!!HEx1&y1=1/x2=0:S23/13;
!!HEx1&y1=2/x2=0:S23/14;
!!HEx1&y1=3/x2=0:S23/15;
那么防御术就被加强成，初级，减20%，中级减40%，专家减60%。
再猜，如果这样写：
!!HEx1&y1=1/x2=0:S23/35;
!!HEx1&y1=2/x2=0:S23/35;
!!HEx1&y1=3/x2=0:S23/35;
那么会防御术的英雄，不论级别多少，防御级别多少，物理伤害永远是1，适合创造boss 。
[ 本帖最后由 fastarrow 于 2010-12-23 00:11 编辑 ] 4楼说得在理，可以用上述方法间接实现防御术的加强，不过实际测试真的很难，尤其是在防御术加强这一块，上面那些数据有的我以前也测试过，有些应该是比较准确的。我在改编《巫妖王毁灭》的过程中，也是用上述方法间接实现进攻、抗魔、战术等英雄技能加强的，不过用于防御术由于测试太难，就没办法下结论了。
其实我觉得用上述方法可以间接实现进攻、防御、抗魔、箭术、战术、弹道等技能的加强（效果可以接近），用TM触发器模拟后勤、航海、理财、神秘、智力等技能加强（效果可以乱真），再用其它方法实现领导、幸运、学习能力、魔力、急救、鹰眼、招魂等技能加强（除领导、幸运外效果比较接近），全技能加强的英雄并不是梦。:deyi: 至于外交术要怎么强化就还搞不懂，原理都不难，我以前试搞过，不过由于测试太难，就没有进行下去。希望版主把它搞出来。
[ 本帖最后由 沧海壹粟 于 2010-12-23 09:34 编辑 ]
回复 7# 的帖子
外交有个等级是无论遇到什么怪物都100%加入的，具体是几忘了，可能是09或者11吧，不过这样搞非常无聊，都100%加入就没什么意思了。可以搞一个英雄遇到自己特长生物的，生物比较有倾向加入
当访问某一种怪物的时候，检查怪物是否是英雄特长生物，之后用MO：R调整怪物敌意。理论上应该可行，但我没有尝试过。
如果MO：R不能实现功能，还可以尝试间接的办法，按比例删去怪物，然后再给英雄增加相应的数量。
今天下午试验了一下!
测试结果如下:S1/5:10%;
S1/6:20%;
S1/7:30%;
S1/17:40%;
S1/18:50%;
S1/19:60%;
S1/43:100%;经过加强108级箭术伤害可达7.4倍伤害, 868级伤害可达45.4倍
S22/6:10%;
S22/7:15%;
S22/17:30%;
S22/13:40%;
S22/14:50%;
S22/15:60%;
S22/39:100%;经过加强108级进攻伤害可达7.4倍伤害,868级伤害可达45.4倍
[ 本帖最后由 xxb19780916 于 2010-12-23 21:07 编辑 ]
如果按100%一加强箭术和进攻术!
那主角特长箭术和进攻的,就更能够发挥的淋漓尽致了!防御术我仍然不建议加强,以前的15%蛮好,一定要到868级才能够免伤害,而且也不适合大型战斗了!
觉得设置最合理了!
防御术88级伤害只有19%,而到了108级伤害只有4%,也是相当的恐怖了!
[ 本帖最后由 xxb19780916 于 2010-12-23 21:04 编辑 ]
按照这样做BOSS的话!
88级防御玩家-----108级箭术或进攻108级防御玩家-----868级箭术或进攻
相对来说:箭术BOSS有相当的难度,不反击,不怕力盾,以前的打法通常有耗箭的,如果在弹药量足够的话,
相信谁碰到都是噩梦!
下面发一下加强箭术和进攻术的脚本,防御术没有加强!
这样感觉进攻和防御还有箭术特长都很好,有的一拼了!
ZVSE
!#TM50:S2/999/1/255;
!#TM51:S8/999/7/255;
!#VRz722:S^{急救帐篷}
每一轮战斗过后，都可以用急救帐篷医治你的部队，并且在战斗胜利后复活部分阵亡的部队，复活的生命总值为(1-50 + 英雄等级)。^;
!#VRz723:S^{弩车}
T弩车可以在战斗中打击敌人的部队，并且在战前直接杀死敌方(1-50 + 英雄等级)点生命值的兵力。^;
!#VRz724:S^{补给车}
补给车可以在战斗中为你的远程攻击部队提供无限量的弹药，并且增加急救帐篷和弩车100%的非战斗效果。^;
!#HT5/6:Tz722;
!#HT5/4:Tz723;
!#HT5/5:Tz724;
!#VRz725:S^补给车^;
!#UN:A5/9/725;
!#VRz713:S^{初级抵抗力}
初级抵抗力可使英雄部队的魔法抵抗力提高10%%。^;
!#VRz714:S^{中级抵抗力}
中级抵抗力可使英雄部队的魔法抵抗力提高20%%。^;
!#VRz715:S^{高级抵抗力}
高级抵抗力可使英雄部队的魔法抵抗力提高30%%。^;
!#UN:G0/26/1/z713 G0/26/2/z714 G0/26/3/z715;
!#VRz716:S^{初级急救术}
初级急救术可使英雄在战斗中自己控制急救帐篷，最多恢复50点生命值。可召唤帐篷，数量为英雄等级，并且行动之后自动施展疗伤魔法。^;
!#VRz717:S^{中级急救术}
中级急救术可使英雄在战斗中自己控制急救帐篷，最多恢复75点生命值。可召唤帐篷，数量为英雄等级，并且行动之后自动施展疗伤魔法。^;
!#VRz718:S^{高级急救术}
高级急救术可使英雄在战斗中自己控制急救帐篷，最多恢复100点生命值。可召唤帐篷，数量为英雄等级，并且行动之后自动施展全体疗伤魔法。^;
!#UN:G0/27/1/z716 G0/27/2/z717 G0/27/3/z718;
!#VRz719:S^{初级}{炮术}
可控制弩车
每轮发射1次
有50%的机会造成2倍的损伤
可控制箭塔^;
!#VRz720:S^{中级}{炮术}
可控制弩车
每轮发射2次
有75%的机会造成2倍的损伤
可控制箭塔^;
!#VRz721:S^{高级}{炮术}
可控制弩车
每轮发射2次
有100%的机会造成2倍的损伤
可控制箭塔^;
!#UN:G0/20/1/z719 G0/20/2/z720 G0/20/3/z721;
!#VRz726:S^{初级}{幸运术}
幸运 +1
开战时有10％的几率暂时为己方1支部队增加2点攻防并获得幸运之神魔法状态。^;
!#VRz727:S^{中级}{幸运术}
幸运 +2
开战时有20％的几率暂时为己方2支部队增加2点攻防并获得幸运之神魔法状态。^;
!#VRz728:S^{高级}{幸运术}
幸运 +3
开战时有30％的几率暂时为己方3支部队增加2点攻防并获得幸运之神魔法状态。^;
!#UN:G0/9/1/z726 G0/9/2/z727 G0/9/3/z728;
!#VRz732:S^{初级}{寻路术}
初级寻路术可使英雄移动时受地形的影响减少25%%，英雄带领的部队地图速度至少为6。^;
!#VRz733:S^{中级}{寻路术}
中级寻路术可使英雄移动时受地形的影响减少50%%，英雄带领的部队地图速度至少为7。^;
!#VRz734:S^{高级}{寻路术}
高级寻路术可使英雄移动时受地形的影响减少75%%，英雄带领的部队地图速度至少为8。^;
!#UN&v7194=1:G0/0/1/z732 G0/0/2/z733 G0/0/3/z734;
!#VRz750:S^{初级}{航海术}
初级航海术可使英雄在海上的移动点数增加50%%，海战时暂时增加英雄攻防各1点。^;
!#VRz751:S^{中级}{航海术}
中级航海术可使英雄在海上的移动点数增加100%%，海战时暂时增加英雄攻防各2点。^;
!#VRz752:S^{高级}{航海术}
高级航海术可使英雄在海上的移动点数增加150%%，海战时暂时增加英雄攻防各3点。^;
!#UN:G0/5/1/z750 G0/5/2/z751 G0/5/3/z752;
!#VRz897:S^{初级}{防御术}
初级防御术可使英雄的部队在遭到攻击时损伤减少5%%。^;
!#VRz898:S^{中级}{防御术}
中级防御术可使英雄的部队在遭到攻击时损伤减少10%%。^;
!#VRz899:S^{高级}{防御术}
中级防御术可使英雄的部队在遭到攻击时损伤减少15%%。^;
!#UN:G0/23/1/z897 G0/23/2/z898 G0/23/3/z899;
!#VRz894:S^{初级魔力}
初级魔力可使英雄在战斗中的魔法杀伤力提高10%%。^;
!#VRz895:S^{中级魔力}
中级魔力可使英雄在战斗中的魔法杀伤力提高20%%。^;
!#VRz896:S^{高级魔力}
高级魔力可使英雄在战斗中的魔法杀伤力提高30%%。^;
!#UN:G0/25/1/z894 G0/25/2/z895 G0/25/3/z896;
!#VRz897:S^{初级箭术}
初级箭术可使英雄在战斗中的远程杀伤力提高30%%。^;
!#VRz898:S^{中级箭术}
中级箭术可使英雄在战斗中的远程杀伤力提高50%%。^;
!#VRz899:S^{高级箭术}
高级箭术可使英雄在战斗中的远程杀伤力提高100%%。^;
!#UN:G0/1/1/z897 G0/1/2/z898 G0/1/3/z899;
!#VRz900:S^{初级进攻术}
初级进攻术可使英雄在战斗中的近战杀伤力提高30%%。^;
!#VRz901:S^{中级进攻术}
中级进攻术可使英雄在战斗中的近战杀伤力提高50%%。^;
!#VRz902:S^{高级进攻术}
高级进攻术可使英雄在战斗中的近战杀伤力提高100%%。^;
!#UN:G0/22/1/z900 G0/22/2/z901 G0/22/3/z902;
** end of Initialization Code
** Timer routines
!?TM94;
!!OW:C?v7026;
!!VRv7020:S0;
!!DO7020/0/155/1:P1;
!?TM50;
!!OW:C?v7026;
!!VRv7020:S0;
!!DO7020/0/155/1:P0;
!?FU7020;
!!HEx16:O?v7021;
!!HEx16:S0/?y1;
!!FU7025&y1>0:Px16/y1;
!?BA0;
** artillery for MP game runs at Attacker's side
!!BA:H0/?v7020;
!!HEv7020&v7020>-1:A2/4/?y-7/?y-8;
!!FU7000&y-8>0/v7020>-1:P1;
!!BA:H1/?v7020;
!!HEv7020&v7020>-1:A2/4/?y-7/?y-8;
!!FU7000&y-8>0/v7020>-1:P2;
!?BA0;
** first aid
!!VRv7040:C0/0/0/0/0/0/0;
!!VRv7047:C0/0/0/0/0/0/0;
!!BA:M0/0/?y-1/?v7040;
!!BA:M0/1/?y-1/?v7041;
!!BA:M0/2/?y-1/?v7042;
!!BA:M0/3/?y-1/?v7043;
!!BA:M0/4/?y-1/?v7044;
!!BA:M0/5/?y-1/?v7045;
!!BA:M0/6/?y-1/?v7046;
!!BA:M1/0/?y-1/?v7047;
!!BA:M1/1/?y-1/?v7048;
!!BA:M1/2/?y-1/?v7049;
!!BA:M1/3/?y-1/?v7050;
!!BA:M1/4/?y-1/?v7051;
!!BA:M1/5/?y-1/?v7052;
!!BA:M1/6/?y-1/?v7053;
!?BA0;
** luck
!!VRv7034:C-2/-2/-2/-2/-2/-2;
!!BA:H0/?v7020;
!!HEv7020&v7020>-1:S9/?y-1;
!!FU7008&y-1>0/v7020>-1:Py-1/1;
!!BA:H1/?v7020;
!!HEv7020&v7020>-1:S9/?y-2;
!!FU7008&y-2>0/v7020>-1:Py-2/2;
!!BA:Od/?y-1;
!!IP&998:Dy-1 V7034/7039; zvs
** start of battle-start trigger
!?BA52;
** offset skill levels for armorer, resistance, sorcery
!!BA:H0/?v7054;
!!BA:H1/?v7055;
!!FU7026&v7054>-1:Pv7054/0;
!!FU7026&v7055>-1:Pv7055/0;
** end of battle-start trigger
!?HM-1|v7193=1/v7197=1;
!!HE-1:N?v7020 O?y-2;
!!OW:C?y-3;
!!FU&y-2<>y-3:E;
!!HEv7020:P?v7023/?v7024/?v7025;
!!TR7023:T?y-5/d/d/d/d/d/d/d;
!!IF:Wv7020;
!!VRw4&v7193=1/y-5<>8:S0;
!!HEv7020&v7193=1/y-5=8:S5/?w4;
** start of battlefield start trigger
!?BF;
** luck
!!BA:H0/?v7020;
!!HEv7020&v7020>-1:S9/?y-1;
!!DO7010/0/20/1&v7020>-1/y-1>0:P1;
!!BA:H1/?v7020;
!!HEv7020&v7020>-1:S9/?y-2;
!!DO7010/21/41/1&v7020>-1/y-2>0:P2;
** navigation
!!BA:H0/?v7020;
!!IF&v7020>-1:Wv7020;
!!DO7024/0/20/1&v7020>-1/w4>0:Pw4;
!!BA:H1/?v7020;
!!IF&v7020>-1:Wv7020;
**
zvs fix
!!DO7024/21/41/1&v7020>-1/w4>0:Pw4;
** end of battlefield start trigger
** start of post-action trigger
!?BG1;
** reset skill levels for armorer, resistance, sorcery
!!BU:C?y-9;
!!FU7026&v7054>-1/y-9=1:Pv7054/1;
!!FU7026&v7055>-1/y-9=1:Pv7055/1;
** end of post-action trigger
!?BA1;
** first aid
!!BA:H0/?v7020;
!!HEv7020&v7020>-1:O?v7021;
!!HEv7020&v7020>-1:S27/?y-8;
!!FU7002&v7021>-1/y-8>0/v7020>-1:P1;
!!BA:H1/?v7020;
!!HEv7020&v7020>-1:O?v7021;
!!HEv7020&v7020>-1:S27/?y-8;
!!FU7002&v7021>-1/y-8>0/v7020>-1:P2;
** reset skill levels for armorer, resistance, sorcery
!!FU7026&v7054>-1:Pv7054/1;
!!FU7026&v7055>-1:Pv7055/1;
** end of battle end trigger
** function to handle artillery, hero v7020, skill level y1
!?FU7000;
!!HEv7020:A2/5/?y7/?y8 E?y3/?y4/1 S20/?y1;
!!VRy5:S1;
!!VRy5&y8>0:+1;
!!VRy5&y1>0:+y1;
!!VRy3:S0 +1 T49 +y4 *y5;
!!VRy2:S0 T6;
!!VRj:S7;
!!DO7001/0/6/1:Px1/y2/y3;
** end of function
** function to check one stack for monsters to shoot
!?FU7001;
x1=slot#
x2=slot
x3=damage
!!HEv7020:B0/?z1;
!!VRy4:Sx2 %7;
!!BA&x1=1:M1/y4/?y5/?y6;
!!BA&x1=2:M0/y4/?y5/?y6;
!!IF:V2/0;
!!IF&j=7/y6>1:V2/1;
!!VRj&2:Sy4;
!!MA&y5>-1:Py5/?y7;
!!VRx3&2/y7>0::y7;
!!VRx3&2/x3>y6:Sy6;
!!VRx3&2/x3=y6:-1;
!!VRy6&2/x3>0:-x3;
!!BA&2/x1=1/x3>0:M1/y4/?y5/y6;
!!BA&2/x1=2/x3>0:M0/y4/?y5/y6;
!!VRy1&2/x3>0:Sx3 *y7;
!!HEv7020&2/x3>0:Edy1;
zvs
!!VRx2:+1;
** end of function
** function to handle first aid tent
!?FU7002;
y1= HP
y2=slot y9= first aid
!!HEv7020:A2/5/?y7/?y8 E?y3/?y4/1 S27/?y9;
!!VRy5:S1;
!!VRy5&y8>0:+1;
!!VRy5&y9>0:+y9;
!!VRy1:S0 +1 T49 +y4 *y5;
!!VRy2:S0 T6;
!!VRj:S7;
!!DO7003/0/6/1:Px1/y1/y2;
** end of function
** function to find slot where at least 1 cr was lost
!?FU7003;
x1=filter x2=hp healed
x3=slot
!!VRy4:Sx3 %7;
!!BA&x1=1:M0/y4/?y5/?y6;
!!BA&x1=2:M1/y4/?y5/?y6;
!!FU|y5<0/y6<1:E;
!!VRy1&x1=1:S7040 +y4;
!!VRy1&x1=2:S7047 +y4;
!!VRy7:Svy1;
!!VRy7:-y6;
!!FU7004&j=7/y7>0/y6>0:Px1/x2/x3/y4/y5/y6/y7;
!!VRx3:+1;
** end of function
** function to heal a stack
!?FU7004;
!!HEv7020:B0/?z1;
!!MA:Px5/?y8;
!!VRy5:Sx2;
[# of hit points to heal]
!!VRy5::y8;
!!VRy5&y5>x7:Sx7;
!!BA&x1=1/y5>0:M0/x4/?x5/dy5;
!!BA&x1=2/y5>0:M1/x4/?x5/dy5;
!!IF&1000/y5=1:Q2/21/x5/1^战斗胜利后, %Z1 用急救帐篷复活了一个生物!^;
!!IF&1000/y5>1:Q2/21/x5/1^战斗胜利后, %Z1 用急救帐篷复活 了 %Y5 个生物!^;
!!UN:R1;
!!VRj&y5>0:Sx4;
** end of function
** function for luck
x1=luck
x2=att/def (1/2)
!?FU7008;
!!HEv7020:B0/?z1;
!!VRy3:Sx1 *10;
!!VRy4:S0;
!!VRy5:S0 T6;
!!DO7009/0/6/1:Px1/x2/y3/y4/y5;
** function to pick slots
!?FU7009;
x1=luck level x2=filter x3=%chance x4=slot counter
x5=random slot #
!!VRy1:Sx5 %7;
!!BA&x2=1:M0/y1/?y2/?y3;
!!BA&x2=2:M1/y1/?y2/?y3;
!!VRy6&y3>0:S0 R99;
!!VRx4&x3>y6/y3>0:+1;
!!VRv7034&x2=1/x3>y6/y3>0/x4=1:Sy1;
!!VRv7035&x2=1/x3>y6/y3>0/x4=2/x1>1:Sy1;
!!VRv7036&x2=1/x3>y6/y3>0/x4=3/x1=3:Sy1;
!!VRv7037&x2=2/x3>y6/y3>0/x4=1:Sy1;
!!VRv7038&x2=2/x3>y6/y3>0/x4=2/x1>1:Sy1;
!!VRv7039&x2=2/x3>y6/y3>0/x4=3/x1=3:Sy1;
!!VRx5:+1;
** end of function
** function to check if unit has luck
!?FU7010;
x1=filter
x16=stack number
!!BMx16:O?y5;
!!FU7011&x1=1/y5=v7034:Px16;
!!FU7011&x1=1/y5=v7035:Px16;
!!FU7011&x1=1/y5=v7036:Px16;
!!FU7011&x1=2/y5=v7037:Px16;
!!FU7011&x1=2/y5=v7038:Px16;
!!FU7011&x1=2/y5=v7039:Px16;
** end of function
** function to give unit luck bonus
!?FU7011;
x1=stack #
x2=stack offset
!!BMx1:A?y1;
!!BMx1:D?y2;
!!VRy1:+5;
!!VRy2:+5;
!!BMx1:Ay1;
!!BMx1:Dy2;
** end of function
** function to pick a monster
!?FU7019;
!!VRs:S0 T173;
!!VRs&s>=132/s<=135:S0 T173;
!!VRs&s>=150/s<=158:S0 T173;
!!VRs&s>=145/s<=149:S0 T131;
!!VRs&s>=160/s<=163:S0 T131;
!!VRs&s=122:S192;
!!VRs&s=124:S193;
!!VRs&s=126:S194;
!!VRs&s=128:S195;
!!UN:N3/z704/s/0;
!!UN:N3/z705/s/1;
** end of function
** function for navigation (add attack and defence)
(Parameters: x1=stat bonus)
!?FU7024;
!!BMx16:Adx1;
!!BMx16:Ddx1;
** end of function
** function for pathfinding
x1 = hero
x2 = pathfinding
x3=Logistics
!?FU7025;
!!HEx1:P?v7023/?v7024/?v7025;
!!TRv7023/v7024/v7025:T?y1/d/d/d/d/d/d/d;
!!FU&y1=8:E;
!!HEx1:W?y2;
!!VRy2&x2=1/y2<1700:S1700;
!!VRy2&x3=1:+200;
!!VRy2&x2=2/y2<1760:S1760;
!!VRy2&x3=2:+300;
!!VRy2&x2=3/y2<1830:S1830;
!!VRy2&x3=3:+400;
!!HEx1:Wy2 Gy2;
** end of function
** function to offset skill levels
!?FU7026;
x1=hero
x2=set/reset
!!HEx1:S23/?y1;
!!HEx1&y1=1/x2=0:S23/1;
!!HEx1&y1=2/x2=0:S23/2;
!!HEx1&y1=3/x2=0:S23/3;
!!HEx1&y1=1/x2=1:S23/1;
!!HEx1&y1=2/x2=1:S23/2;
!!HEx1&y1=3/x2=1:S23/3;
!!HEx1:S25/?y2;
!!HEx1&y2=1/x2=0/x1<>140:S25/-3;
!!HEx1&y2=2/x2=0/x1<>140:S25/-2;
!!HEx1&y2=3/x2=0/x1<>140:S25/-1;
!!HEx1&y2=-3/x2=1/x1<>140:S25/1;
!!HEx1&y2=-2/x2=1/x1<>140:S25/2;
!!HEx1&y2=-1/x2=1/x1<>140:S25/3;
!!HEx1&y2=1/x2=0/x1=140:S25/-15;
20%
!!HEx1&y2=2/x2=0/x1=140:S25/-14;
40%
!!HEx1&y2=3/x2=0/x1=140:S25/-17;
60%
!!HEx1&y2=-15/x2=1/x1=140:S25/1;
!!HEx1&y2=-14/x2=1/x1=140:S25/2;
!!HEx1&y2=-17/x2=1/x1=140:S25/3;
************************
!!HEx1:S22/?y9;
!!HEx1&y9=1/x2=0:S22/17;
30%
!!HEx1&y9=2/x2=0:S22/14;
50%
!!HEx1&y9=3/x2=0:S22/39;
100%
!!HEx1&y9=17/x2=1:S22/1;
!!HEx1&y9=14/x2=1:S22/2;
!!HEx1&y9=39/x2=1:S22/3;
************************
!!HEx1:S1/?y10;
!!HEx1&y10=1/x2=0:S1/7;
30%
!!HEx1&y10=2/x2=0:S1/18;
50%
!!HEx1&y10=3/x2=0:S1/43;
100%
!!HEx1&y10=7/x2=1:S1/1;
!!HEx1&y10=18/x2=1:S1/2;
!!HEx1&y10=43/x2=1:S1/3;
************************
!!HEx1:S26/?y3;
!!HEx1&y3=1/x2=0:S26/9;
!!HEx1&y3=2/x2=0:S26/10;
!!HEx1&y3=3/x2=0:S26/11;
!!HEx1:A2/57/?y5/?y7 A2/58/?y5/?y8 A2/59/?y5/?y9;
!!VRy6&y7>0/y8>0/y9>0:S1;
!!HEx1&y3=0/y6=1/x2=2:S26/-17;
!!HEx1&y3=1/y6=1/x2=2:S26/-7;
!!HEx1&y3=2/y6=1/x2=2:S26/-6;
!!HEx1&y3=3/y6=1/x2=2:S26/-5;
!!HEx1&y3=9/x2=1:S26/1;
!!HEx1&y3=10/x2=1:S26/2;
!!HEx1&y3=11/x2=1:S26/3;
!!HEx1&y3=-17/x2=1:S26/0;
!!HEx1&y3=-7/x2=1:S26/1;
!!HEx1&y3=-6/x2=1:S26/2;
!!HEx1&y3=-5/x2=1:S26/3;
** end of function
** function to iterate through current player's heroes (weekly)
!?FU7012;
!!HEv7020:O?v7021;
!!HEv7020&v7021=v7026:S13/?y1;
!!FU7013&v7188=1/v7021=v7026/y1>0:Py1;
*!HEv7020&v7021=v7026:S18/?y1;
*!FU7014&v7196=1/v7021=v7026/y1>0:Py1;
*!VRv7020:+1;
** end of function
** function for estates
x1=estates level
!?FU7013;
!!HEv7020:B0/?z700;
!!HEv7020:R2/?y1;
!!IF:Wv7020;
!!VRw5&w8<1/x1>0:S0 R5;
!!VRw6&w8<2/x1>1:S0 R5;
!!VRw7&w8<3/x1=3:S0 R5;
!!VRw8&w8=0/x1>0:S1;
!!VRw8&w8=1/x1>1:S2;
!!VRw8&w8=2/x1=3:S3;
!!VRy3:S1 R2;
!!VRy3&w5=0|w5=2:*2;
!!VRy4:S1 R2;
!!VRy4&w6=0|w6=2:*2;
!!VRy5:S1 R2;
!!VRy5&w7=0|w7=2:*2;
!!IFv7020&1000/x1=1:Q2/w5/y3/1^%Z700 的理财术生产了一些资源。^;
!!IFv7020&1000/x1=2:Q2/w5/y3/w6/y4/1^%Z700 的理财术生产了一些资源。^;
!!IFv7020&1000/x1=3:Q2/w5/y3/w6/y4/w7/y5/1^%Z700 的理财术生产了许多资源。^;
!!OW&x1=1:Rv7021/w5/dy3;
!!OW&x1=2:Rv7021/w5/dy3 Rv7021/w6/dy4;
!!OW&x1=3:Rv7021/w5/dy3 Rv7021/w6/dy4 Rv7021/w7/dy5;
** end of function
**
object trigger - post visit - Garniture of Interference
!$OB5/57;
!!FU7007:P2;
**
object trigger - post visit - Surcoat of Counterpoise
!$OB5/58;
!!FU7007:P2;
**
object trigger - post visit - Boots of Polarity
!$OB5/59;
!!FU7007:P2; 你们都厉害，居然研究到了这个地步。看来我落后太多啦。ERM不进则退啊。:lianhong: 入来观赏:lianhong: 瞅瞅。。。。看不懂，外行看热闹了:lianhong: 太长了，只能高山仰止，欣赏了 我的天，我怎么会看这个贴的？:shangxin: 强烈请教，怎么使高级寻路术对地形的影响减少100%
原语句：高级寻路术可使英雄移动时受地形的影响减少75%%，英雄带领的部队地图速度至少为8。^;
!#UN&v7194=1:G0/0/1/z732 G0/0/2/z733 G0/0/3/z734;
请指教。 原帖由 兽哥哥 于 2011-6-23 19:59 发表 http://www.wogcn.net/images/common/back.gif
我的天，我怎么会看这个贴的？:shangxin:
兽哥加油。。。。。。在WOG，只有想不到的，没有办不到的。。。 原帖由 jvtcjll 于 2012-1-7 10:23 发表 http://www.h3wog.com/images/common/back.gif
强烈请教，怎么使高级寻路术对地形的影响减少100%
原语句：高级寻路术可使英雄移动时受地形的影响减少75%%，英雄带领的部队地图速度至少为8。^;
!#UN&v7194=1:G0/0/1/z732 G0/0/2/z733 G0/0/3/z734;
请指教。
呵呵，你那句代码只是关于寻路术的说明，要使高级寻路术对地形的影响减少100%，说简单也简单说复杂也复杂，其实说明部分已经有提示了“英雄带领的部队地图速度至少为8”换成100%的话，就是“至少为10了”。
页:
[1]
2
