【数据恢复】战役跨关宠物/追随者/第二追随者数据保存ERM(含第二追随者ERM)
原贴作者为woodmelon，最初于2006-3-24 17:41发表在本论坛似乎有点多余,小黑有宠物保存脚本了.不过那个不能保存追随者数据.
我加上吧,顺便附带加上了第二追随者属性保存脚本,算是三合一吧
使用方法(手动的,小黑的是全自动!)
1.注意数据保存的脚本必须放在第二追随者脚本之前,普通追随者脚本之后!!!一旦搞错将无法保存!按我默认的序号就一定没问题.
原版追随者脚本是Script49
属性保存脚本是Script87
第二追随者脚本是Script88
像这样的顺序就不会有问题
放到Data/s目录下,WoG化任何地图有效(你不开启追随者和宠物选项就无言了)
2.游戏中大地图右键点击"地图选项"图标触发(系统选项左边那个).决定保存数据后,每次对游戏进行存档时,都会保存三者的数据!跨关时好像是必须存档的,所以这个是没问题的.当然也可以随时取消.
3.下一场景开始后,会询问是否还原上一场景的数据.你可以自由选择是否还原或者单一还原三者其中一个.
*******
说明:
1.只可以保存20位己方英雄的数据,超过20的也只会保存前20个.当然这个数字你自己也可以手动改大,不过估计战役地图也不能携带这么多英雄过场.
2.由于保存宠物数据用到大量的W变量,所以请注意其他脚本是否和该脚本有冲突.还是一句话:"绝对不会与原版的WOG脚本冲突".
脚本贴出来让大家共同研究吧.当然懒人可以到脚本最下方直接下载.
ZVSE
ERMS_ScriptDate=24.3(March).2006
ERMS_Script by woodmelon
** WOG原版追随者脚本所用变量
*w117 追随者经验
*w118 追随者ID
*w119 追随者是否生存: 1=生存
*请把追随者的ERM(script49)放到该脚本之前
** 第二追随者脚本所用变量
*w160 第二追随者ID
*w161 第二追随者经验
*w162 第二追随者是否死亡 1=生存
*w163 第二追随者特技
*w164 第二追随者经验特技
*请把第二追随者的ERM放到该脚本之后
** 本脚本所使用的变量
*v1-v21: 临时变量,请勿用于储存其他重要数据!!!
** 不能改变以下变量的值:
*w165: 0=生存 512=死亡0~8/512~520=类型
*W166: 经验
*w167: 等级
*w168-w179 宠宝
*w180: 特技
*w181~186: 宠宝和战斗次数
*w187~192: 六项基本技能
*w187~w192:六项状态
*w193: 追随者
*FU25010
*flag: 590,591,592,593
*1.大地图上右键点击"地图选项"图标触发.
*2.己方不允许多于20个英雄,否则只能保留前20个英雄的数据
*3.该脚本仅对战役地图有效,请不要利用本脚本去玩一般地图
!#TM19:S1/1/1/255; TM19源于script00.erm
!?CM0;
!!CM:I?y91 S?y92;
!!FU|y91<>9/y92<>14:E;
!!CM:R0;
!!VRv2:S1;
!!VRv2&593:S0;
!!VRz1&v2=1:S^你想保存宠物和追随者的数据,以便跨场景时使用吗?^;
!!VRz1&v2=0:S^你想取消保存宠物和追随者的数据吗?^;
!!IF:D90///1////////////;
!!IF:F90/////1;
!!IF:E1/90;
!!IF&v1=5:V593/v2;
!?GM1&593; 存档
!!OW:H-1/21/0; 获取英雄数目
!!VRv21&v21>20:S20; 读取前20英雄的名字
!!DO25010/1/v21/1&v21>0:P0; 检查己方英雄
!!DO25010/1/v21/1&v21>0:P1; 保存宠物和追随者数据
**跨关后
!?PI&593;
!!VRz1:S^读取上一场景哪个生物的数据?
宠物和第二追随者所有状态保留,普通追随者仅保留其战斗经验^;
!!VRz2:S^宠物^;
!!VRz3:S^普通追随者^;
!!VRz4:S^第二追随者^;
!!VRz5:S^全部无视^;
!!IF:G0/1/7/1/2/3/4/5;
!!VRv2:Cv1/v1/v1/v1;
!!VRv2:&8;
!!IF&v2>0:V590/0 V591/0 V592/0 V593/0; 重置
!!FU&v2>0:E; 全部无视
!!VRv3:&1;
!!IF&v3>0:V590/1; 宠物数据保留
!!IF&v3=0:V590/0; 宠物数据不保留
!!VRv4:&2;
!!IF&v4>0:V591/1; 追随者数据保留
!!IF&v4=0:V591/0; 追随者数据不保留
!!VRv5:&4;
!!IF&v5>0:V592/1; 第二追随者数据保留
!!IF&v5=0:V592/0; 第二追随者数据不保留
!?TM19&593/1000;
!!OW:H-1/21/0; 获取英雄数目
!!FU&v21<0:E;
!!VRv21&v21>20:S20; 读取前20英雄的名字
!!DO25010/1/v21/1:P0; 检查己方英雄
!!DO25010/1/v21/1|590/591:P2; 读取数据
!?FU25010;
!!OW&x1=0:H-1/x16/x16; 逐个检查英雄
!!FU&x1=0:E;
!!IF:Wvx16; 读取英雄变量
!!VRy93:Svx16;
!!COy93&w166>0/x1=2:E1; 跨关后英雄若没有宠物则自动追加
!!COy93:E?y91; 英雄是否有宠物
!!VRw166&y91=0:S0; 无宠物的英雄宠物经验清0
!!FU&y91=0:E;
!!COy93&x1=1:D?y91 T?y92; 是否死亡/类型
!!VRy91&y91=1/x1=1:S512;
!!VRw165&x1=1:Sy91; 0=生存 512=死亡
!!VRw165&x1=1:+y92; 类型=0~8/512~520
!!COy93&x1=1:X1/?w166; 经验
!!COy93&x1=1:X2/?w167; 等级
!!COy93&x1=1:A4/?w168/?w169/?w170/?w171/?w172/?w173/?w174/?w175/?w176/?w177/?w178/w?179; 宠宝
!!COy93&x1=1:B0/?w180; 特技
!!COy93&x1=1:S0/?w181; 六项基本技能
!!COy93&x1=1:S1/?w182;
!!COy93&x1=1:S2/?w183;
!!COy93&x1=1:S3/?w184;
!!COy93&x1=1:S4/?w185;
!!COy93&x1=1:S5/?w186;
!!COy93&x1=1:P0/?w187; 六项状态
!!COy93&x1=1:P1/?w188;
!!COy93&x1=1:P2/?w189;
!!COy93&x1=1:P3/?w190;
!!COy93&x1=1:P4/?w191;
!!COy93&x1=1:P5/?w192;
!!VRw193&x1=1:Sw118; 追随者
!!VRw118&x1=2/591:Sw193; 保留追随者
**跨关后
!!FU|x1<2/-590:E;
!!COy93&w165>=512:D1; 标记死亡
!!COy93&w165<=8:D0; 标记生存
!!VRw165&w165>=512:-512;
!!COy93:Tw165; 复原类型
!!COy93:X1/w166; 经验
!!COy93:X2/w167; 等级
!!COy93:A4/w168/w169/w170/w171/w172/w173/w174/w175/w176/w177/w178/w179; 宠宝
!!COy93:B0/w180; 特技
!!COy93:S0/w181; 七项基本技能
!!COy93:S1/w182;
!!COy93:S2/w183;
!!COy93:S3/w184;
!!COy93:S4/w185;
!!COy93:S5/w186;
!!COy93:S6/w185;
!!COy93:P0/w187; 七项状态
!!COy93:P1/w188;
!!COy93:P2/w189;
!!COy93:P3/w190;
!!COy93:P4/w191;
!!COy93:P5/w192;
!!COy93:P6/w191; 好东东，少了不少手脚。 介个就素在战役下比较有用吧？ 我的追随者有点问题 下过来看看|！！！！！！ :-_-b: 好东东
感谢啊 好东西，可惜没钱了 现在就差好战役了 xiexie 谢谢~！;hap; 哦,谢谢了~我去试一试~~ 支持 好东西。可惜下不了。真郁闷 郁闷呀。 要多少才能下？ ;lihong; ;lihong; ;lihong; ;lihong; ;lihong; ;sjiao; ;sjiao; ;sjiao; ;sjiao; ;hap; ;hap; ;hap; ;shxin; ;shxin; ;daj; ;daj; ;daj; ;daj;
